The Word MVP Site

• Word Home
• Word:mac
• Troubleshoot
• Tutorials
• Find Help
• About Us
• Contact
• Sitemap

• Up to Home

  General

  • Word's numbering explained
  • Remove manually typed numbering
  • Safely update a document's styles from its template

  Page Numbering

  • “Page X of Y” displays or prints as “Page 1 of 1,” “Page 2 of 2” (or “Page 2 of 1”) and so on
  • How to control the page numbering in a Word document
  • Why do all the page numbers in my Word 2002 document display as 0?
  • Front matter numbered separately
  • Include the chapter number with the page number

  List Numbering

  • Word's numbering explained
  • Methods for restarting list numbering
  • VBA: Return the number, or list level, or outline level of a paragraph.

  Other

  • Whenever I update my Table of Contents it acquires unwanted tabs
  • Customizing your table of contents with switches
  • Automatic "intentionally blank" page
  • How can I use an AutoNum field but suppress the period after the number or use a different separator character?
  • Create a numbered list using SEQuence fields
  • How to insert captions that include chapter numbers
  • Creating sequentially numbered documents (such as invoices)
  • Sequentially numbering multiple copies of single document using a macro
  • Sequentially numbering multiple copies of single document using a mailmerge

Create a numbered list using SEQuence fields

Article contributed by Dave Rado, based on an article by Bill Coan Bill Coan,
with thanks also to Doug Robbins

Sub CreateNumberedList()

'to apply/re-apply numbering to a range of paragraphs
'using ranges is faster than using selections, and reduces flicker

Application.ScreenUpdating = False

Dim MyRange As Range, DummyRange As Range, _
SelectedRange As Range, Counter As Long

Set SelectedRange = Selection.Range

For Counter = 1 To SelectedRange.Paragraphs.Count

    Set MyRange = SelectedRange.Paragraphs(Counter).Range

     'check para contains some text, if not, skips this para
    If Len(MyRange.Text) = 1 Then
        GoTo MissOut
    End If

     'Deletes existing seq field if present

    Set MyRange = SelectedRange.Paragraphs(Counter).Range

    If MyRange.Characters(1).Fields.Count > 0 Then
        If MyRange.Fields(1).Type = wdFieldSequence Then
            MyRange.Fields(1).Delete
            'deletes the dot and tab as well
            MyRange.End = MyRange.Characters(2).End
            MyRange.Delete
        End If
    End If

    'insert new sequence field

    MyRange.Collapse

    'first create a dummy range object and move it to the right one,
    'so that it will end up being located AFTER the field you're adding.
    'This is necessary because when you add a field to a range,
    'the range (unlike selection) ends up at the start of the field!!!
    'this is one of the unfortunate "features" of ranges

    Set DummyRange = MyRange.Duplicate
    DummyRange.Move unit:=wdCharacter, Count:=1

    MyRange.Fields.Add Range:=MyRange, _
            Type:=wdFieldEmpty, Text:="SEQ numberedlist\r" & Counter, _
            PreserveFormatting:=True
    Set MyRange = DummyRange.Duplicate
    MyRange.Move unit:=wdCharacter, Count:=-1

    'Set paragraph indents as desired for list

    With MyRange.ParagraphFormat
        .LeftIndent = CentimetersToPoints(1.27)
        .FirstLineIndent = CentimetersToPoints(-1.27)
    End With

    MyRange.InsertAfter "." & vbTab

MissOut:

Next Counter

SelectedRange.Select
Application.ScreenUpdating = True

End Sub